[FRAGE]Vb 08 Datei in Autostart

Imports Microsoft.Win32
Imports System.Collections.Generic
Imports System.Linq
Imports System.Text


''' <summary>
''' Utility.
''' </summary>
Public Class Util
    Private Const RUN_LOCATION As String = "Software\Microsoft\Windows\CurrentVersion\Run"

    ''' <summary>
    ''' Sets the autostart value for the assembly.
    ''' </summary>
    ''' <param name="keyName">Registry Key Name</param>
    ''' <param name="assemblyLocation">Assembly location (e.g. Assembly.GetExecutingAssembly().Location)</param>
    Public Shared Sub SetAutoStart(ByVal keyName As String, ByVal assemblyLocation As String)
        Dim key As RegistryKey = Registry.CurrentUser.CreateSubKey(RUN_LOCATION)
        key.SetValue(keyName, assemblyLocation)
    End Sub

    ''' <summary>
    ''' Returns whether auto start is enabled.
    ''' </summary>
    ''' <param name="keyName">Registry Key Name</param>
    ''' <param name="assemblyLocation">Assembly location (e.g. Assembly.GetExecutingAssembly().Location)</param>
    Public Shared Function IsAutoStartEnabled(ByVal keyName As String, ByVal assemblyLocation As String) As Boolean
        Dim key As RegistryKey = Registry.CurrentUser.OpenSubKey(RUN_LOCATION)
        If key Is Nothing Then
            Return False
        End If

        Dim value As String = DirectCast(key.GetValue(keyName), String)
        If value Is Nothing Then
            Return False
        End If

        Return (value = assemblyLocation)
    End Function

    ''' <summary>
    ''' Unsets the autostart value for the assembly.
    ''' </summary>
    ''' <param name="keyName">Registry Key Name</param>
    Public Shared Sub UnSetAutoStart(ByVal keyName As String)
        Dim key As RegistryKey = Registry.CurrentUser.CreateSubKey(RUN_LOCATION)
        key.DeleteValue(keyName)
    End Sub
End Class

Util.SetAutoStart("MeinProgramm", pfadZurExe)