VB.net Send Keys + Clicks without focus

06/07/2015 20:02 zǝro#1

Guten Abend,

Ich suche nach einem Weg Keys und Clicks in einem minimierten Programm zu emulieren.

Beispiel:
SendKeys.Send("A")
SendKeys.Send("F11")
Mouseclick at x,y
SendKeys.Send("F11")

Das Programm soll kein Focus bekommen also alles im Hintergrund erledigen.
Ich habe es bereits so versucht, aber es sendet ja nur einen Text und keine Keys:

Code:

Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
                  (ByVal lpClassName As String, ByVal lpWindowName As String) As IntPtr
    Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
                     (ByVal hWnd As IntPtr, ByVal hWndChildAfterA As IntPtr, ByVal lpszClass As String, ByVal lpszWindow As String) As IntPtr
    Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
                     (ByVal hWnd As IntPtr, ByVal wMsg As Integer, ByVal wParam As IntPtr, ByVal lParam As String) As IntPtr
    Const WM_SETTEXT As Integer = &HC

Private Sub BotGuildBank()
        Dim destination As IntPtr = FindWindow(Nothing, "TITLE")
        Dim destControl As IntPtr = FindWindowEx(destination, IntPtr.Zero, "Edit", Nothing)
        SendMessage(destControl, WM_SETTEXT, IntPtr.Zero, "A")
    End Sub

Hab google schon durchsucht, vielleicht wei� von euch ja jemand einen Rat ^^

06/07/2015 20:06 YatoDev#2

Code:

[DllImport("user32.dll", CharSet = CharSet.None, ExactSpelling = false, SetLastError = true)]
        private static extern bool PostMessage(int hWnd, uint Msg, int wParam, int lParam);

Nach jedem aufruf:

Code:

PostMessage((int)handle, 0x0006, 0, 0);

06/09/2015 18:28 snow#3

#moved…

06/12/2015 19:09 anonymous-29742#4

:) > SendKeys im Minimierten Fenster.

Spoiler

Code:

Imports System.Runtime.InteropServices

Public Class Form1

    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _
Private Shared Function SendMessage(ByVal hWnd As IntPtr, ByVal Msg As UInteger, ByVal wParam As IntPtr, ByVal lParam As IntPtr) As IntPtr
    End Function

    <DllImport("User32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _
  Private Shared Function EnumChildWindows(ByVal WindowHandle As IntPtr, ByVal Callback As EnumWindowProcess, ByVal lParam As IntPtr) As Boolean
    End Function

    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _
 Private Shared Sub GetClassName(ByVal hWnd As System.IntPtr, ByVal lpClassName As System.Text.StringBuilder, ByVal nMaxCount As Integer)
    End Sub

    Public Shared Function GetChildWindows(ByVal ParentHandle As IntPtr) As IntPtr()
        Dim ChildrenList As New List(Of IntPtr)
        Dim ListHandle As GCHandle = GCHandle.Alloc(ChildrenList)
        Try
            EnumChildWindows(ParentHandle, AddressOf EnumWindow, GCHandle.ToIntPtr(ListHandle))
        Finally
            If ListHandle.IsAllocated Then ListHandle.Free()
        End Try

        Return ChildrenList.ToArray
    End Function

    Public Delegate Function EnumWindowProcess(ByVal Handle As IntPtr, ByVal Parameter As IntPtr) As Boolean
    Private Shared Function EnumWindow(ByVal Handle As IntPtr, ByVal Parameter As IntPtr) As Boolean
        Dim ChildrenList As List(Of IntPtr) = GCHandle.FromIntPtr(Parameter).Target
        If ChildrenList Is Nothing Then Throw New Exception("GCHandle Target could not be cast as List(Of IntPtr)")
        ChildrenList.Add(Handle)
        Return True
    End Function

    Private Const WM_CHAR = &H102

    Private Sub TextBox1_KeyDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown
        If e.KeyCode = Keys.Enter Then
            e.SuppressKeyPress = True
            For Each P As Process In Process.GetProcesses
                If P.ProcessName = "notepad" Then
                    For Each I As IntPtr In GetChildWindows(P.MainWindowHandle)
                        Dim L As Integer = 256
                        Dim sb As New System.Text.StringBuilder(L)
                        GetClassName(I, sb, L)
                        If sb.ToString = "Edit" Then
                            For Each c As Char In TextBox1.Text
                                SendMessage(I, WM_CHAR, Asc(c), 0)
                            Next
                            SendMessage(I, WM_CHAR, Keys.Enter, 0)
                            TextBox1.Clear()
                            Return
                        End If
                    Next
                End If
            Next
        End If
    End Sub
End Class

MFG #Lucas#