[D]dasocks - Async Sockets

import dasocks;

// Only required for bind() and Client test
import std.socket : InternetAddress, TcpSocket;
import std.stdio;

void main() {
	// Creates an asynchronous socket server
	auto server = new AsyncTcpSocket;
	// Sets the events of the server
	server.setEvents(new AsyncSocketEvent(&onAccept), new AsyncSocketEvent(&onReceive), new AsyncSocketEvent(&onDisconnect));
	// Begins to accept a connection
	server.beginAccept();	
	// Binds the server to 127.0.0.1:9988
	server.bind(new InternetAddress("127.0.0.1", 9988));
	// Starts listening for connections
	server.listen(500);
	
	// Client test ...
	writeln("Press ENTER to connect...");
	readln();
	// Creates a new NON-asynchronous tcp socket
	auto client = new TcpSocket;
	// Connects to 127.0.0.1:9988
	client.connect(new InternetAddress("127.0.0.1", 9988));
	writeln("Connected...");
	while (true) {
		writeln("Press ENTER to send a packet...");
		readln();
		// Creates a 10 byte packet
		ubyte[] buffer = [0, 1, 2, 3, 4, 5, 6, 7, 8, 9];
		// Sends the packet
		client.send(buffer);
	}
}

void onAccept(AsyncTcpSocket server) {
	// Ends the acceptance of a socket and returns the accepted socket
	auto socket = server.endAccept();
	writeln("Socket[", socket.socketId, "] has connected.");
	// Begins to receive a 10 byte packet from the accepted socket
	socket.beginReceive(10);
	
	// Begins to accept a new connection
	server.beginAccept();
}

void onReceive(AsyncTcpSocket client) {
	import std.conv : to;
	
	// Gets the received packet from the client
	ubyte[] buffer = client.endReceive();
	string outStr;
	foreach (b; buffer)
		outStr ~= to!string(b) ~ ", ";
	outStr.length -= 2;
	writeln("[", outStr, "] from Socket[", client.socketId, "]");
	
	// Begins to receive a 10 byte packet from the client
	client.beginReceive(10);
}

void onDisconnect(AsyncTcpSocket socket) {
	if (socket.listening) {
		// If the socket is listening then it's a server socket
		writeln("The server was shutdown!");
	}
	else {
		// If the socket isn't listening then it's a client
		writeln("Socket[", socket.socketId, "] has disconnected.");
	}
}