pls help bei aimbot

02/03/2009 19:26 GGyRRoSS#1
Kann mir jemand eventuel das hier vor scripten!

Scrip start
mouse start 800*600
mouse bewegt sich zu pixel!
wenn mouse pixel erreicht
mouseclick ("left")
Mouse bewegt sich zurück nach 800*600
prozess wiederholt ganze zeit wenn pixel auftaucht



so konnte man doch einen Aimbotbasteln zb. nur headshots oder liege ich da falsch?
02/03/2009 19:45 fieser-hund#2
is richtig
du machst screenshot
fügst in paint ein
und dann pixelsearch
dann haste nen pixel vom kopf :D
02/03/2009 20:20 Adroxxx#3
Quote:
Originally Posted by GGyRRoSS View Post
Kann mir jemand eventuel das hier vor scripten!

Scrip start
mouse start 800*600
mouse bewegt sich zu pixel!
wenn mouse pixel erreicht
mouseclick ("left")
Mouse bewegt sich zurück nach 800*600
prozess wiederholt ganze zeit wenn pixel auftaucht



so konnte man doch einen Aimbotbasteln zb. nur headshots oder liege ich da falsch?

Grundlegend richtig. Aber ganz so einfach ist es dann doch nicht.
Erstmal brauchst du einen Eindeutigen Pixel vom Kopf. Ist auch nicht immer so einfach.
Und dieses "Pozess wiederholt ganze zeit [...]" ist auch nicht ganz so einfach. Du kannst den Prozess nicht einfach in eine Unendlich schleife packen, musst auf jedenfall kleinere pausen dazwischen machen.


Hier mal der Source von einem Aimbot:


PHP Code:
This tutorial was not written by me it was written by Helios of ArtificialAiming.net. As you who cheat FPS's know he charges a monthly fee to use his framework FPS cheats and aimbots so hopefully you can learn to make your own from this source code of his UT aimbot code.

Project : HelioS Aimbot Tutorial (UT Edition)
Version : 1.0
Coder : [ELF]HelioS
Site : http://users.skynet.be/HelioS/Main
================================================== ===================================


Setting up your project


1) Go to the Unreal Tournament Root directory and make a new directory named "MyAimbot"
2) In that directory make 2 more direcotry's named "Classes" and "Textures"

Now your directory structure should look like this

UnreaTournament
+ Cache
+ Editor
+ Help
+ Logs
+ Maps
+ Music
+ MyAimbot
+ Classes
+ Textures
+ Sounds
+ System
+ Textures
+ Web

3) Open the "UnrealTournament.ini" located in the "UnrealTournament\System" directory
4) Search for "Console=UTMenu.UTConsole" and replace it with "Console=MyAimbot.MyConsole"
5) Now search for "EditPackages=" and add "EditPackages=MyAimbot" at the end of the list

You should have

EditPackages=Core
EditPackages=Engine
EditPackages=Editor
EditPackages=UWindow
EditPackages=Fire
EditPackages=IpDrv
EditPackages=UWeb
EditPackages=UBrowser
EditPackages=UnrealShare
EditPackages=UnrealI
EditPackages=UMenu
EditPackages=IpServer
EditPackages=Botpack
EditPackages=UTServerAdmin
EditPackages=UTMenu
EditPackages=UTBrowser
EditPackages=MyAimbot

6) Save the .ini file and go back to the "UnrealTournament\MyAimbot" directory
8) In that directory create a new .bat file named "CompileMyAimbot.bat"
This will make compiling the Aimbot easier later on
Edit the new .bat file and write

cd..
cd System
Del MyAimbot.u
UCC.exe Make
Pause

7) Go to the "UnrealTournament\MyAimbot\Classes" directory and create a new empty text file
and name it "MyConsole.uc"

8) Open the "MyConsole.uc" file with any text editor you like
NotePad or WordPad should work fine
Now we can start the actual Programming/Scripting



Programming a simple Aimbot


You should have "MyConsole.uc" open by now

The Actual Bot code


//================================================== ===================================
// BOT START.
//================================================== ===================================

class MyConsole extends UTConsole Config(MyAimbot);
// MyConsole : This must match the filename you are programming in
// UTConsole : This is the Class your script extends
// Config(MyAimbot) : Your bot settings will be saved in the "MyAimbot.ini" file


#exec Texture Import File=Textures\MyCross.bmp Name=MyCross
#exec Texture Import File=Textures\MyLogo.bmp Name=MyLogo
// #exec lines are used to tell the compiler it should Import a texture or sound
// In this case you will Import the file "MyCross.bmp" and give it the variable name "MyCross"
// The same goes for MyLogo.bmp


// if a config statement is before the variable, you will be able to save the variable into "MyAimbot.ini"
var config bool bBotActive;
var config bool bAutoAim;
var config bool bAutoFire;
var config bool bDrawRadar;


// These vars will not be saved to the .ini file
var PlayerPawn Me;
var bool bBotIsShooting;


// Hook into the PostRender event to get Canvas acces
// If you have Canvas acces you are able to write and show stuff onto your Screen
event PostRender (Canvas Canvas)
{
Super.PostRender(Canvas);
// This will execute all the code that is located into the "PostRender" event we have just overwritten
// Don't forget this

MyPostRender(Canvas);
// Ok now execute our own code located into the "MyPostRender" function
// We pass on Canvas acces to our function too so we can Draw stuff on Screen
}


//================================================== ==============================
// MAIN BOT.
//================================================== ==============================


// This is where the magic happens
// It is the start of our own Aimbot code
function MyPostRender (Canvas Canvas)
{

Me = Viewport.Actor;
// We give the Variable "Me" the value "Viewport.Actor"
// "Me" now hold our own Player (PlayerPawn)


// This is a check if we activated our Aimbot
// And we check if the variable Me is NOT None
// You must be carefull that a variable you use is not None because
// it can lead to enormous errors and even a crash of UT
if (!bBotActive || Me == None || Me.PlayerReplicationInfo == None)
{
Return;
// If we didn't activate our aimbot or the Me variable is None
// we stop this function with the "Return" statement
}

// Now execute our Code that is located in the Function below and give them all Canvas acces
DrawMyLogo(Canvas);
DrawMySettings(Canvas);
PawnRelated(Canvas);
}


// Let us draw a nice bot logo on screen so you can show off your newly created aimbot to your friends
function DrawMyLogo (Canvas Canvas)
{
Canvas.Style = 3;
// set the Canvas Style to transparant

Canvas.bCenter = False;
// we don't want it in the center of the screen

Canvas.bNoSmooth = True;

// Divide the screen height by 3
Canvas.SetPos(20, Canvas.ClipY / 3);

// set the DrawColor to White
Canvas.DrawColor.R = 229;
Canvas.DrawColor.G = 229;
Canvas.DrawColor.B = 229;
Canvas.DrawColor.A = 0;

// Draw our 1337 Logo
Canvas.DrawIcon(Texture'MyLogo', 0.7);
}


// It is allways usefull to show on screen what features of the Aimbot are On/Off
function DrawMySettings (Canvas Canvas)
{
// set the Font to small so we don't fill up an entire screen by just writing some settings
Canvas.Font = Canvas.SmallFont;

Canvas.SetPos(20, Canvas.ClipY / 2);
Canvas.DrawText("[MyAimbot]");

Canvas.SetPos(20, Canvas.ClipY / 2 + 10 );
Canvas.DrawText("----------");

Canvas.SetPos(20, Canvas.ClipY / 2 + 20);
Canvas.DrawText("AutoAim : " $ String(bAutoAim));

Canvas.SetPos(20, Canvas.ClipY / 2 + 30);
Canvas.DrawText("AutoFire : " $ String(bAutoFire));

Canvas.SetPos(20, Canvas.ClipY / 2 + 40);
Canvas.DrawText("Radar : " $ String(bDrawRadar));

}


// This function holds the code that will cycle through all Players on the Map
function PawnRelated(Canvas Canvas)
{
local Pawn Target;
local Pawn BestTarget;

// Cycle through all players (Pawns) on the Map and store them in a temporarry variable "Target"
foreach Me.Level.AllActors(Class'Pawn', Target)
{
// Check if this Target is Valid, we don't want to be Aiming at spectator or people that are allready dead
if ( ValidTarget(Target) )
{
// Check if the feature "DrawRadar" is active
if ( bDrawRadar )
{
DrawPlayerOnRadar(Target, Canvas);
// execute the code that will draw this Target in our 3D Radar
}

// Check if the feature "AutoAim" is active
if ( bAutoAim )
{
// Check to see that this Target should be considered as a target to aim at
if ( GoodWeapon() && IsEnemy(Target) && PlayerVisible(Target) )
{
BestTarget = GetBestTarget(BestTarget, Target);
// The "GetBestTarget" function will return the BestTarget we have so far
// So lets store it in the variable "BestTarget"
// Notice that "BestTarget" can change when we progress through our Player Cycle
}
}
}
}

// Check to see if the bot managed to get a Target to Aim at
if ( BestTarget != None )
{
SetMyRotation(BestTarget);
// execute the code that will set our Rotation so we look directly at the "BestTarget"

// Check if the feature "AutoFire" is active
if ( bAutoFire )
{
FireMyWeapon();
// execute the code that will make our Weapon Fire
}
}
else
{
StopMyWeapon();
// If we don't have a Target to Aim at we should stop our weapon from shooting
}
}


// This function gets called from the "PawnRelated" function to see if a Target is Valid
function bool ValidTarget (Pawn Target)
{
if (
(Target != None) && // Target variable is Not Empty
(Target != Me) && // Target is Not ower own Player
(!Target.bHidden) && // Target is Not hidden
(Target.bIsPlayer) && // Target is an actual player
(Target.Health > 0) && // Target is still alive
(!Target.IsInState('Dying')) && // Target is Not Dying
(!Target.IsA('StaticPawn')) && // Target is Not a Static Box or Crate
(Target.PlayerReplicationInfo != None) && // Target has Replication info
(!Target.PlayerReplicationInfo.bIsSpectator) && // Target is Not a spectator
(!Target.PlayerReplicationInfo.bWaitingPlayer) // Target is Not somebody that is pending to get into the game
)
{
Return True;
// If all the above condition are met we return True else we return False
}
else
{
Return False;
}
}


// This function gets called from the "PawnRelated" function to see if a Target is the Opposit Team
function bool IsEnemy (Pawn Target)
{
// Check to see if we are in a Teambased Gamemode
if ( Me.GameReplicationInfo != None && Me.GameReplicationInfo.bTeamGame )
{
// Check to see if Target is on the Opposit Team
if ( Target.PlayerReplicationInfo.Team != Me.PlayerReplicationInfo.Team )
{
Return True;
}
else
{
Return False;
}
}
else
{
Return True;
// If it is not a Teambased game every Target is an Enemy
}
}


// This function gets called from the "PawnRelated" function to see if we are holding a Good Weapon
function bool GoodWeapon ()
{
if (
( Me.Weapon != None ) && // Our Weapon is Not None
( Me.Weapon.AmmoType != None ) && // Our Weapon uses Ammo
( Me.Weapon.AmmoType.AmmoAmount > 0) // We still have Ammo left
)
{
Return True;
}
else
{
Return False;
}
}


// This function gets called from the "PawnRelated" function to see which Target is better
function Pawn GetBestTarget (Pawn BestTarget, Pawn Target)
{
local float BestDistance;
local float CurrentDistance;

if ( BestTarget == None )
{
Return Target;
// If we don't have a BestTarget Yet we return the current Target
}
else
{
// We allready have a BestTarget, so let's see if our new Target is closer
// Store the Distance of both Targets is 2 variables
BestDistance = VSize(BestTarget.Location - Me.Location);
CurrentDistance = VSize(Target.Location - Me.Location);

if ( CurrentDistance < BestDistance )
{
Return Target;
// Our new Target is Closer so lets return the new Target to become the BestTarget
}
else
{
Return BestTarget;
// Our BestTarget is still closer so just return the same BestTarget
}
}
}


// This function gets called from the "PawnRelated" function to see if a Target is Visible
function bool PlayerVisible (Pawn Target)
{
local vector HisLocation;
local vector MyLocation;

// Store our location in a vector and add our EyeHeight to it
// so we have a vector that holds the place of our Eyes
MyLocation = Me.Location;
MyLocation.Z += Me.BaseEyeHeight;

// Store the Target's location in a vector
// We can't add their EyeHeight to it because the Server doesn't send the correct value to Client
HisLocation = Target.Location;
HisLocation.Z += Target.CollisionHeight * 0.7;

// Lets do a Trace from our location to his location
// The Trace will return true if there is no object blocking the path between both Vectors
// Notice that Tracing takes up CPU power and a lot of Traces will cause UT to run slow or lag
if ( Me.FastTrace(HisLocation, MyLocation) )
{
Return True;
}
else
{
Return False;
}
}


// This function gets called from the "PawnRelated" function to set our View direclty to the BestTarget
function SetMyRotation (Pawn BestTarget)
{
local vector AimLocation;
local rotator AimRotation;
local vector MyLocation;

// Same stuff we did before
MyLocation = Me.Location;
MyLocation.Z += Me.BaseEyeHeight;

// Same stuff we did before
AimLocation = BestTarget.Location;
AimLocation.Z += BestTarget.CollisionHeight * 0.7;

// Store the needed Rotation we have to make to aim at the BestTarget
AimRotation = Normalize( rotator( AimLocation - MyLocation ) );

// Do the Actual Rotation
Me.ViewRotation = AimRotation;
Me.SetRotation(AimRotation);
Me.ClientSetLocation(Me.Location,AimRotation);

}


// This function gets called from the "PawnRelated" function to Start Fireing
function FireMyWeapon ()
{
// set BotIsShooting to true so we can use this variable later to check if the bot is shooting or we shot manually
bBotIsShooting = True;

// Turn on Primary Fire an Simulate that we are pressing the Fire Button
Me.bFire=1;
Me.bAltFire=0;
Me.Fire();
}


// This function gets called from the "PawnRelated" function to Stop our weapon
function StopMyWeapon ()
{
// Check to see if the bot turned on fire or we shot manually
if ( bBotIsShooting )
{
// The bot stopped shooting so lets set BotIsShooting to false
bBotIsShooting = False;

// Deactivate all fire modes
Me.bFire=0;
Me.bAltFire=0;
}
}


// This function gets called from the "PawnRelated" function to Draw a Player in the 3D Radar
function DrawPlayerOnRadar (Pawn Target, Canvas Canvas)
{
local vector MyLocation;
local vector TargetLocation;
local vector DiffLocation;
local vector X,Y,Z;

local float ScreenPosX;
local float ScreenPosY;

local string DistanceInfo;
local string HealthInfo;
local string NameInfo;

// I think you know this by now
MyLocation = Me.Location;
MyLocation.Z += Me.EyeHeight;

// And again
TargetLocation = Target.Location;
TargetLocation.Z += Target.CollisionHeight / 2;

// Substract both locations and store it in a variable
DiffLocation = TargetLocation - MyLocation;

// This is a bit more complicated
// We have to devide our own ViewRotation into different axels
GetAxes(Normalize(Me.ViewRotation),X,Y,Z);

// Check to see if the Player is Not behind us
// If we didn't do this check we should draw players on the radar that are behind us
if (DiffLocation Dot X > 0.70)
{
// This is even more complicated
// It converts a vector in a 3D space to a 2D Screen
// It takes into acount the Screen Resolution and the Zoom level that you are currently using
ScreenPosX = (Canvas.ClipX / 2) + ( (DiffLocation Dot Y)) * ((Canvas.ClipX / 2) / Tan(Me.FovAngle * Pi/360)) / (DiffLocation Dot X);
ScreenPosY = (Canvas.ClipY / 2) + (-(DiffLocation Dot Z)) * ((Canvas.ClipX / 2) / Tan(Me.FovAngle * Pi/360)) / (DiffLocation Dot X);

// Set the position or on Screen so we can draw a cross at that position
Canvas.SetPos(ScreenPosX - 8, ScreenPosY - 8);
// Set the DrawColor to match the TeamColor of the Target
Canvas.DrawColor = GetTeamColor(Target);
// Draw the actual Cross on Screen
Canvas.DrawIcon(Texture'MyCross', 0.5);


// A cross on a screen doesn't hold much info so lets draw some extra info next to it
NameInfo = Target.PlayerReplicationInfo.PlayerName;
HealthInfo = "H: " $ String(Target.Health);
DistanceInfo = "D: " $ String(Int(VSize(DiffLocation) / 48));

// Set the Font of your text to small so we don't fill up an entire screen
Canvas.Font = Canvas.SmallFont;

// Draw the Extra Info next to then Cross
Canvas.SetPos(ScreenPosX + 10, ScreenPosY - 8 );
Canvas.DrawText(NameInfo);

Canvas.SetPos(ScreenPosX + 10, ScreenPosY );
Canvas.DrawText(HealthInfo);

Canvas.SetPos(ScreenPosX + 10, ScreenPosY + 8);
Canvas.DrawText(DistanceInfo);

}
}


// This function gets called from the "DrawPlayerOnRadar" function to determine the TeamColor of a Target
function Color GetTeamColor (Pawn Target)
{
local Color TeamColor;

// Determine which Team the Target is on
switch( Target.PlayerReplicationInfo.Team )
{
Case 0: // Red Team
TeamColor.R = 229;
TeamColor.G = 60;
TeamColor.B = 60;
TeamColor.A = 0;
Break;

Case 1: // Blue Team
TeamColor.R = 90;
TeamColor.G = 160;
TeamColor.B = 229;
TeamColor.A = 0;
Break;

Default: // Green or Default Team
TeamColor.R = 60;
TeamColor.G = 229;
TeamColor.B = 60;
TeamColor.A = 0;
Break;
}

Return TeamColor;
}


// function to make it easier to show some Extra Info
function Msg (string Message)
{
if ( Me != None )
{
Me.ClientMessage(Message);
// Add this Message to the Console and HUD
}
}


//================================================== ==============================
// BOT COMMANDS.
//================================================== ==============================


// Function that start with "exec" can be called from within the Console Menu
// All functions below are used to Toggle the Aimbot Featurs
// Bot Commands are "doActive" "doAutoAim" "doAutoFire" "doRadar" "doSave"

exec function doActive ()
{
bBotActive = !bBotActive;
Msg("Aimbot Active = " $ string(bBotActive));
}

exec function doAutoAim ()
{
bAutoAim = !bAutoAim;
Msg("AutoAim = " $ string(bAutoAim));
}

exec function doAutoFire ()
{
bAutoFire = !bAutoFire;
Msg("AutoFire = " $ string(bAutoFire));
}

exec function doRadar ()
{
bDrawRadar = !bDrawRadar;
Msg("Radar = " $ string(bDrawRadar));
}

exec function doSave ()
{
// We want to save some settings to the "MyAimbot.ini" file so lets call a Native function to do that
SaveConfig();
StaticSaveConfig();
Msg("Settings Saved");
}


//================================================== ==============================
// DEFAULTS.
//================================================== ==============================

defaultproperties
{
// The variables will hold these values from the start
// Do NOT use Spaces here
bBotActive=True;
bAutoAim=True;
bAutoFire=True;
bDrawRadar=True;
}


//================================================== ===================================
// BOT END.
//================================================== ===================================



How to Compile the Aimbot

Just DoubleClick on the "CompileMyAimbot.bat" file
If all went like planned there will be "MyAimbot.u" in your "UnrealTournament\System" Directory


Aimbot Commands

Type these commands in Console while you are playing

doActive : to toggle the full Aimbot on/off
doAutoAim : to toggle AutoAim on/off
doAutoFire : to toggle AutoFire on/off
doRadar : to toggle 3D Player Radar on/off
doSave : to save all bot settings


Extra Stuff you need to know

You can find a precoded Aimbot source in the Tutorial
But without all the extra comment

This Aimbot will only work on Servers that are NOT Protected by any AntiCheat Software

Please give me credit if you use this Tutorial as a base for your working Aimbot
I took the time to write this Tutorial and I don't like to see my work Ripped by others

I Hope you have learned something from this :D
Good luck on the creation of your Aimbot! 
02/03/2009 20:35 GGyRRoSS#4
enlosschleife würde gehen kein ding ^^

habe texturen verändert beim spiel schiese einfach durch die wände durch ^^ und gehe durch? ja aber nur durch die seiten wände^^

naja hab mir nen wallhack gedownloadet
wo alies einen hellblauebn punkt auf der stirn und axis einen hellroten punkt auf der stirn haben dann würde ich mir 2bots machen
:D
wenn i9ch bei axi bin starte ich alie bot
wenn bei alie bin axi bot^^


mal so ne frage

wie kann ich machen das ein buchstabe rauskomm habs versuchtmit send

send ("hallo^^")
aber ich wusste irgenwie schon das es falsch ist war nur so ein gefühl trozdme wollte ich testen^^
02/03/2009 21:08 Adroxxx#5
Quote:
Originally Posted by GGyRRoSS View Post
enlosschleife würde gehen kein ding ^^

habe texturen verändert beim spiel schiese einfach durch die wände durch ^^ und gehe durch? ja aber nur durch die seiten wände^^

naja hab mir nen wallhack gedownloadet
wo alies einen hellblauebn punkt auf der stirn und axis einen hellroten punkt auf der stirn haben dann würde ich mir 2bots machen
:D
wenn i9ch bei axi bin starte ich alie bot
wenn bei alie bin axi bot^^


mal so ne frage

wie kann ich machen das ein buchstabe rauskomm habs versuchtmit send

send ("hallo^^")
aber ich wusste irgenwie schon das es falsch ist war nur so ein gefühl trozdme wollte ich testen^^
Was meinst du mit Buchstaben rauskommt? Im Spiel oder was?
Also Send ist da eigentlich schon richtig. Wenn du z.B. willst das der Bot was im Chat schreibt, musst du
PHP Code:
Send("{ENTER}")
Send("Hallo")
Send("{ENTER}") 
Mittels Send() kannst du halt auch Tastatureingaben simulieren.

Also drückt er auf Enter , der Chat öffnet sich, er gibt Hallo ein und drückt wieder Enter zum Absenden.
02/04/2009 03:57 verT!c4L#6
In welcher Sprache ist bitte noch gleich der Aimbot Source ? ó.Ò

@GGyRRoSS:
Kannst dir bitte etwas Zeit nehmen beim tippen? Es liest sich
dann ungemein leichter wovon du versuchst zu erzählen ^^
02/04/2009 04:22 Adroxxx#7
Quote:
Originally Posted by verT!c4L View Post
In welcher Sprache ist bitte noch gleich der Aimbot Source ? ó.Ò
Das ist ein UT script. Geht ja auch net um die Sprache sondern Grundlagen. Aimbot ist ja meistens von den Grundlagen her gleich aufgebaut und die Sprache ist ja da egal.

Hab irgendwo noch n C Source rumfliegen von einem sehr einfachem AimBot. Werd ich bei gelegenheit mal raussuchen.

Wer es richtig machen will hier : [Only registered and activated users can see links. Click Here To Register...]
02/04/2009 08:00 GGyRRoSS#8
Ja ich tippe meistens so schnell das ich viele tasten einfach überfliege xD
naja thx für link^^

ich versteh einfach nicht warum das so schwer sien muss^^ er soll nur auf den pixel code ziehlen ganze zeit^^ aber ich krege das einfach nicht hin xD
wenn man ja entlos machen konnte wär es super weil er würde doch dann auto auf die farbe ziehlensobald sie um die ecke kommt dann müsste ich mich ja nur in die mitte der map stehelen nicht das ich das nötig hätte:P



ohne hackz geh ich locker aus der runde mit dem 3-4 fachen kills von Deahts mit wallhack (ohen durch wand schiesen,laufen) 12-13 fache mein bestes ergebniss war bis jetzt

nohack
48/48
only bash aber nur für mich^^
192kills to 48deahts ja das war lustig^^
den screen habe ichauch noch irgendwo^^
brauche immer 4-2schläge pro schlag ^^
naja wenns prenslich wurde habe ich ihm in den fus geschossen und nochmal zugeschlagen dann brauch ich nur noch 1nen schlag^^
aber das war das beste ergebnis bei ego no cheatz:D


@Adroxx konnte man nicht eine entlosschleife rein machen die erst reagiert wenn man z.b linke maus taste drückt^^

pls help bei diesem hier erklärung wenns geht bitte^^



$left PixelSearch ("left", "top", "right", "bottom", 0x00F0FF)



ich habe mir das so gedacht^^

ich kopiere xmal das hier

$left = mouseclick ("left")

$left PixelSearch ("left", "top", "right", "bottom", 0x00F0FF)

also meine idde wars eigentlich das wenn ich dann left clicke das der den pixel 0x00F0FF anzeihlt^^ aber das ist woll bissle zu hoch für mich^^
02/04/2009 13:09 Adroxxx#9
Quote:
Originally Posted by GGyRRoSS View Post
$left PixelSearch ("left", "top", "right", "bottom", 0x00F0FF)
Bei left, top , right und bottom gibst du dir kooridinaten an, in welchem bereich der pixel gesucht werden soll. So wählt du halt ein quadrat oder rechteck aus auf deinem bildschirm.
02/04/2009 16:17 __wadim#10
Quote:
ich versteh einfach nicht warum das so schwer sien muss^^ er soll nur auf den pixel code ziehlen ganze zeit^^ aber ich krege das einfach nicht hin xD
wenn man ja entlos machen konnte wär es super weil er würde doch dann auto auf die farbe ziehlensobald sie um die ecke kommt dann müsste ich mich ja nur in die mitte der map stehelen nicht das ich das nötig hätte:P
Code:
While True
	$leftmouse = _IsPressed(0x1)
	if $leftmouse = 1 Then
		$found = PixelSearch(0, 0, @DesktopHeight, @DesktopWidth, 0xDeineFarbe, 10)
		if Not @error Then
			MouseClick("left", $found[0], $found[1], 1)
		EndIf
	EndIf
WEnd
was kann man da nicht hinbekommen?
aber mit sowas wirst du nicht weitkommen :) ist doch kein aimbot
hab script nicht getestet...

edit:
hab eben das gefunden..: [Only registered and activated users can see links. Click Here To Register...]
02/04/2009 21:07 Atheuz#11
Quote:
Originally Posted by Adroxxx View Post
Das ist ein UT script. Geht ja auch net um die Sprache sondern Grundlagen. Aimbot ist ja meistens von den Grundlagen her gleich aufgebaut und die Sprache ist ja da egal.

Hab irgendwo noch n C Source rumfliegen von einem sehr einfachem AimBot. Werd ich bei gelegenheit mal raussuchen.

Wer es richtig machen will hier : [Only registered and activated users can see links. Click Here To Register...]
Das einen hat aber nichts mit dem anderen zu tun.

Was du gepostet hast war ein Memory basierender Aimbot der über Vektoren verläuft. Was der Threadersteller will ist was auf Pixelbasis. Der Junge ist schon damit total überfordert, da kannst du nicht noch von Leuten erwarten das Sie das verstehen.
02/04/2009 21:11 Adroxxx#12
Quote:
Originally Posted by Atheuz View Post
Das einen hat aber nichts mit dem anderen zu tun.

Was du gepostet hast war ein Memory basierender Aimbot der über Vektoren verläuft. Was der Threadersteller will ist was auf Pixelbasis. Der Junge ist schon damit total überfordert, da kannst du nicht noch von Leuten erwarten das Sie das verstehen.
Ich habe ja auch extre geschrieben "Wer es richtig machen will" ;-) PixelBots sind doch eh für die Tonne. Wozu seine Zeit damit verschwenden. Direkt richtig machen *g*
02/04/2009 21:46 GGyRRoSS#13
hmm ich hab das mal so geändert wie ichs haben wollte

While True
$leftmouse = _IsPressed (0x1)
if $letfmouse = 1 Then
$found = PixelSearch(0, 0, @DesktopHeight, @DesktopWidth, 0x00F0FF, 10)
if Not @error Then
MouseClick("left", $found[0], $found[1], 1)
EndIf
EndIf
sleep (500)
WEnd

aber

kommt
ERROR unknow function name bei :$leftmouse = _IsPressed (0x1)



habs mal mit dieser vorlage versucht^^

Orginal


HotKeySet("{F5}","start")
HotKeySet("{F6}","ende")

Global $check

Func start()
$pos = MouseGetPos()

$farbe = PixelGetColor($pos[0],$pos[1])
$check = False
While 1
If $check = True Then ExitLoop
$coord = PixelSearch(300,400,1000,800,$farbe)
If not @error Then
MouseMove($coord[0],$coord[1],0)
MouseClick("left")
EndIf
WEnd
EndFunc

Func ende()
$check = True
EndFunc

While 1
Sleep(1000)
WEnd

meine leicht veränderte version^^

HotKeySet("{F5}","start")
HotKeySet("{F6}","ende")

Global $check

Func start()
$pos = MouseGetPos()

$farbe = PixelGetColor ($pos[0], $pos[1], 0x00F0FF)
$check = False
While 1
If $check = True Then ExitLoop
$coord = PixelSearch(300,400,1000,800,$farbe)
If not @error Then
MouseMove($coord[0],$coord[1],0)
MouseClick("left")
EndIf
sleep (500)
WEnd
EndFunc

Func ende()
$check = True
EndFunc

While 1
Sleep(500)
WEnd
02/04/2009 22:05 __wadim#14
Quote:
aber

kommt
ERROR unknow function name bei :$leftmouse = _IsPressed (0x1)
kp wo die funktion _ispressed genau nochmal war, kannst aber genau so gut getasynckeystate nehmen.
02/04/2009 22:24 GGyRRoSS#15
hmm naja mal schauen hoffe ich finde es

HotKeySet("{F5}","start")
HotKeySet("{F6}","ende")

Global $check

Func start()
$pos = MouseGetPos()

$farbe = PixelGetColor ($pos[0], $pos[1], 0x00F0FF)
$check = False
While 1
If $check = True Then ExitLoop
$coord = PixelSearch(300,400,1000,800,$farbe)
If not @error Then
MouseMove($coord[0],$coord[1],0)
MouseClick("left")
EndIf
sleep (500)
WEnd
EndFunc

Func ende()
$check = True
EndFunc

While 1
Sleep(500)
WEnd

Da ist mir irgendwo ein fehler unterlaufen!
die mouse zieht nurmaximum hoch maximum runter!
im wechsel kurse jede 0,5sek
irgendetwas habe ich falsch gemacht ich glaube es liegt daran

$coord = PixelSearch(300,400,1000,800,$farbe)

aber ich bin nicht sicher^^


funn vid ^^
hatte grad nix zu tuhen
[Only registered and activated users can see links. Click Here To Register...]