[RELEASE] M�Fish

Quote:

Originally Posted by kurdi34

bei mir ist der selbe fall ja 32bit windows
hmm komisch, kann mir jetzt nicht erkl�ren woran das liegen soll also wenn nikchtmal ein neustart hilft macht mein installer vllt irgendwas falsch. Kann jetzt leider nich testen worans genau liegt ich hab zur zeit kein 32 Bit windows.

Falls sich einer mit NSIS auskennt oder so hier ist das installer script:
Spoiler
PHP Code:

			
;//////////////////////////////////////////////////////////////////////////////////////////

;//                               M�Fish Installer                                       //

;//////////////////////////////////////////////////////////////////////////////////////////



!include MUI2.nsh ;Neues User Inteface



!define PRODUCT_NAME            "M2Fish"

!define PRODUCT_VERSION         "4.0"

!define PRODUCT_PUBLISHER       "ErpeL"

!define PRODUCT_DIR_REGKEY      "Software\Microsoft\Windows\CurrentVersion\App Paths\M2Fish.exe"

!define PRODUCT_UNINST_KEY      "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"

!define PRODUCT_UNINST_ROOT_KEY "HKLM"

!define INSTALL_FILE_PATH       "C:\Users\ErpeL\Documents\RAD Studio\Projekte\M2\Installer\Files\"



BrandingText "M�Fish by ErpeL" ;Markenname, ersetzt Nullsoft Install System vX.XX



!define MUI_BGCOLOR "c4c4c4"           ;Hintergrundfarbe Header, Willkommensseite

!define MUI_ICON    "Images\SetupIcon.ico" ;Installer Icon



;MUI Einstellungen

!define MUI_HEADERIMAGE                                   ;Headerbild

!define MUI_HEADERIMAGE_BITMAP "Images\Header.bmp"        ;Headerbild

!define MUI_WELCOMEFINISHPAGE_BITMAP "Images\Welcome.bmp" ;Willkommensbild

!define MUI_FINISHPAGE_NOAUTOCLOSE                        ;Verhindert das MUI_PAGE_INSTFILES automatisch geschlossen wird



;Installationnseiten

!insertmacro MUI_PAGE_WELCOME    ;Willkommensseite

!insertmacro MUI_PAGE_DIRECTORY  ;Ordnerauswahl

!insertmacro MUI_PAGE_COMPONENTS ;Was soll installiert werden

!insertmacro MUI_PAGE_INSTFILES  ;auflistung installierter Dateien

!insertmacro MUI_PAGE_FINISH     ;Fertigseite



;Alle Spreachen erlauben (auch andere codepage)

!define MUI_LANGDLL_ALLLANGUAGES



;Sprachen

!insertmacro MUI_LANGUAGE "German"

!insertmacro MUI_LANGUAGE "English"

!insertmacro MUI_LANGUAGE "French"

!insertmacro MUI_LANGUAGE "Greek"

!insertmacro MUI_LANGUAGE "Italian"

!insertmacro MUI_LANGUAGE "Korean"

!insertmacro MUI_LANGUAGE "Polish"

!insertmacro MUI_LANGUAGE "Portuguese"

!insertmacro MUI_LANGUAGE "Romanian"

!insertmacro MUI_LANGUAGE "Russian"

!insertmacro MUI_LANGUAGE "Spanish"



;Produktname und Speicherorte

Name            "${PRODUCT_NAME} ${PRODUCT_VERSION}"  ;Name und Version das Produkts

OutFile         "${PRODUCT_NAME} ${PRODUCT_VERSION} Setup.exe"                           ;Setup Datei

InstallDir      "$PROGRAMFILES\M2Fish"                ;Installationspfad

InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""      ;Registry eintrag mit Pfad zur EXE

                                                



;Kompunenten die bei der Inatllation gew�hlt bzw abgew�hlt werden k�nnen



;Komponete M2Fish--------------------------------------------------------------------------

Section "M2Fish 4.0" SEC01

  SetOutPath "$INSTDIR"

  

  ;Dateien nur �berschreiben wenn neuer als schon installierte

  SetOverwrite ifnewer

    File "${INSTALL_FILE_PATH}M2Fish.exe"

    File "Files\M2Fish.dll"

    File "Files\Alarm.mp3"

    File "Files\Start.bat"

  

  ;Verkun�pfungen erstellen

  CreateDirectory "$SMPROGRAMS\M2Fish"                                  ;Startmen�verzeichnis erstellen

  CreateShortCut  "$SMPROGRAMS\M2Fish\M2Fish.lnk" "$INSTDIR\M2Fish.exe" ;Startmen�verkn�pfung erstellen

  CreateShortCut  "$DESKTOP\M2Fish.lnk" "$INSTDIR\M2Fish.exe"           ;Desktopverkn�pfung erstellen 

SectionEnd



;Komponente Dokumentation------------------------------------------------------------------

Section "User Manual" SEC02

    File "${INSTALL_FILE_PATH}Manual.pdf"

SectionEnd



;Komponente Statistic Reader---------------------------------------------------------------

Section "Statistic Reader" SEC03

    File "${INSTALL_FILE_PATH}Statistic Reader.exe"

    

    CreateDirectory "$SMPROGRAMS\M2Fish"                                                      ;Startmen�verzeichnis erstellen

    CreateShortCut  "$SMPROGRAMS\M2Fish\Statistic Reader.lnk" "$INSTDIR\Statistic Reader.exe" ;Startmen�verkn�pfung erstellen

    CreateShortCut  "$DESKTOP\Statistic Reader.lnk" "$INSTDIR\Statistic Reader.exe"           ;Desktopverkn�pfung erstellen 

SectionEnd



;-AdditionalIcons--------------------------------------------------------------------------

Section -AdditionalIcons

  CreateShortCut "$SMPROGRAMS\M2Fish\Uninstall.lnk" "$INSTDIR\uninst.exe"

SectionEnd



;-Post-------------------------------------------------------------------------------------

Section -Post

  WriteUninstaller "$INSTDIR\uninst.exe"

  WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\M2Fish.exe"

  WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "Path" "$INSTDIR\"

  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName"     "$(^Name)"

  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"

  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon"     "$INSTDIR\M2Fish.exe"

  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion"  "${PRODUCT_VERSION}"

  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher"       "${PRODUCT_PUBLISHER}"

SectionEnd



;Insatll OnInit----------------------------------------------------------------------------

Function .onInit

  !insertmacro MUI_LANGDLL_DISPLAY

FunctionEnd



;//////////////////////////////////////////////////////////////////////////////////////////

;//                                Unistall                                              //

;//////////////////////////////////////////////////////////////////////////////////////////



;Uninstall OnInit--------------------------------------------------------------------------

Function un.onInit

  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "M�chten Sie $(^Name) und alle seinen Komponenten deinstallieren?" IDYES +2

  Abort

FunctionEnd



;Uninstall OnUninstSuccess-----------------------------------------------------------------

Function un.onUninstSuccess

  HideWindow

  MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) wurde erfolgreich deinstalliert."

FunctionEnd



;Uinstall----------------------------------------------------------------------------------

Section Uninstall

  Delete "$INSTDIR\uninst.exe"

  Delete "$INSTDIR\Alarm.mp3"

  Delete "$INSTDIR\M2Fish.dll"

  Delete "$INSTDIR\M2Fish.exe"

  Delete "$INSTDIR\Manual.pdf"

  Delete "$INSTDIR\Statistic Reader.exe"

  Delete "$INSTDIR\Start.bat"

  Delete "$INSTDIR\Settings.dat"



  Delete "$SMPROGRAMS\M2Fish\Uninstall.lnk"

  Delete "$SMPROGRAMS\M2Fish\M2Fish.lnk"

  Delete "$SMPROGRAMS\M2Fish\Statistic Reader.lnk"

  Delete "$DESKTOP\M2Fish.lnk"

  Delete "$DESKTOP\Statistic Reader.lnk"



  RMDir "$SMPROGRAMS\M2Fish"

  RMDir "$INSTDIR"



  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"

  DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"

  SetAutoClose true

SectionEnd